**************************
* corners: HP26 Process corners
*
* This file contains descriptions of the important process corners.
* Corners are composed of a combination of N and P speeds, voltage
* levels and temperatures. 
*   
* Corners are:  fast, slow, left-transfer, right-transfer
* LV
*.protect   

.lib ff-corner
.temp 15   
.param vdd=5.5v 
.model nmos nmos level=28 acm=2 tref=30 ldif=0 hdif=1u tlev=1 bex=-1.5 
+ fex=-1.2 tcv=-1.3m capop=4 meto=0.08u xqc=0.4 mj=0.425 mjsw=0.29 pb=0.27 
+ php=0.45 js=1.0m rsh=0 lref=20u wref=20u vfb0=-464m lvfb=-386m wvfb=400m 
+ phi0=558m lphi=190.9m wphi=-153m k1=756m lk1=284m wk1=-417m k2=30.2m 
+ lk2=153m wk2=-219m n0=1.98 ln0=0 wn0=-152 u00=53.5m lu0=18.2m wu0=-28m 
+ x2u0=1.33m lx2u0=724u wx2u0=-30.8m x2m=10.15 lx2m=-3.24 wx2m=-30 x2e=6.27m 
+ lx2e=-37m wx2e=0 x2u1=7.8m lx2u1=-7m wx2u1=0 x3e=-5.48m lx3e=-61m wx3e=0 
+ x3ms=86.7 lx3ms=400 wx3ms=0 x33m=5k lx33m=0 wx33m=0 u1=497u lu1=123m wu1=0 
+ x3u1=-1.51m lx3u1=121m wx3u1=0 b1=1.115 lb1=96m wb1=0 b2=101m lb2=51m wb2=0 
+ eta0=4.19m leta=56m weta=0 alpha=0 lalpha=0 walpha=0 vcr=0 lvcr=0 wvcr=0 
+ tox=16.1n wd=198n ld=220n muz=475 lmuz=55 wmuz=-50 cj=150u cjsw=365p 
+ cgdo=181p cgso=181p 

.model pmos pmos level=28 acm=2 tref=30 ldif=0 hdif=1u tlev=1 bex=-1.45 
+ fex=-1.0 tcv=1.7m capop=4 meto=0.08u xqc=0.4 mj=0.460 mjsw=0.225 pb=0.78 
+ php=0.42 js=1.0m rsh=0 lref=20u wref=20u vfb0=-316m lvfb=-83.3m wvfb=181m 
+ phi0=775m lphi=-26m wphi=-140m k1=533m lk1=-81.6m wk1=-20m k2=0 lk2=409um 
+ wk2=-7m n0=1.44 ln0=0 wn0=-14.4m u00=74m lu0=14.7m wu0=-52.5m x2u0=4.06m 
+ lx2u0=-10.9m wx2u0=23m x2m=6.65 lx2m=-3.92 wx2m=5.39 x2e=0 lx2e=-2.69m 
+ wx2e=3.11m x2u1=4.13m lx2u1=561u wx2u1=107u x3e=0 lx3e=-309u wx3e=-1.14m 
+ x3ms=6.71 lx3ms=38.25 wx3ms=-23.12 x33m=131 lx33m=1.665 wx33m=-94.4 
+ u1=-4.37m lu1=137m wu1=20.5m x3u1=-4.45m lx3u1=-14m wx3u1=2.10m b1=1.22 
+ lb1=183m wb1=-42.96m b2=157m lb2=62m wb2=-43.42m eta0=0 leta=11m weta=7.32m 
+ alpha=0 lalpha=0 walpha=0 vcr=0 lvcr=0 wvcr=0 tox=16.1n wd=263n ld=196n 
+ muz=150 lmuz=10 wmuz=-22 cj=590u cjsw=280p cgdo=256p cgso=256p 
.endl   


.lib ss-corner
*=====================  s l o w 'p'    s l o w  'n' 
.lib 'lib/models' ps 
.lib 'lib/models' ns 
.temp 75   
.param vdd=4.5v 
.endl   
*   

*==================== s l o w 'p'    f a s t 'n' 
.lib sf-corner
.lib 'lib/models' ps 
.lib 'lib/models' nf 
.temp 25
.param vdd=5v   
.endl   
*   
*===================  f a s t 'p'   s l o w 'n' 
.lib fs-corner
.lib 'lib/models' pf 
.lib 'lib/models' ns 
.temp 25
.param vdd=5v   
.endl   
